<?xml version="1.0" encoding="utf-8"?>
<mx:ModuleLoader xmlns:mx="http://www.adobe.com/2006/mxml" currentState="loading">
	<mx:states>
		<mx:State name="loading">
			<mx:SetStyle name="horizontalAlign" value="center"/>		<!-- Align progress bar to center -->
			<mx:SetStyle name="verticalAlign" value="middle"/>			<!-- Align progress bar to middle -->
			<mx:AddChild position="lastChild">
				<mx:ProgressBar id="progressBar" labelPlacement="center" mode="manual"/>
			</mx:AddChild>
		</mx:State>
	</mx:states>
 
	<mx:Script>
		<![CDATA[
			import mx.modules.IModuleInfo;
			import mx.events.FlexEvent;
			import mx.modules.ModuleManager;
			import mx.events.ModuleEvent;
 
			private var module:IModuleInfo;
 
			override public function loadModule():void
			{
			    if (url == null)
			        return;
 
			    if (child)
			        return;
 
			    if (module)
			        return;
 
			    dispatchEvent(new FlexEvent(FlexEvent.LOADING));
 
			    module = ModuleManager.getModule(url);
 
			    module.addEventListener(ModuleEvent.PROGRESS, moduleProgressHandler);
			    module.addEventListener(ModuleEvent.SETUP, moduleSetupHandler);
			    module.addEventListener(ModuleEvent.READY, moduleReadyHandler);
			    module.addEventListener(ModuleEvent.ERROR, moduleErrorHandler);
			    module.addEventListener(ModuleEvent.UNLOAD, moduleUnloadHandler);
 
			    module.load(applicationDomain);
			}
 
			private function moduleProgressHandler(event:ModuleEvent):void
			{
			    dispatchEvent(event);
 
			    try
			    {
			    	progressBar.setProgress(event.bytesLoaded / event.bytesTotal, 1);
			    }
			    catch(e:Error)
			    {
			    }
			}
 
			private function moduleSetupHandler(event:ModuleEvent):void
			{
			    // Not ready for creation yet, but can call factory.info().
 
			    dispatchEvent(event);
			}
 
			private function moduleReadyHandler(event:ModuleEvent):void
			{
			    child = module.factory.create() as DisplayObject;
			    dispatchEvent(event);
 
			    if (child)
			    {
			        var p:DisplayObjectContainer = parent;
			        // p.removeChild(this);
			        addChild(child);
 
			        setStyle('horizontalAlign', '');			// Reset horizontalAlign
			        setStyle('verticalAlign', '');				// Reset verticalAlign
			    	currentState = '';
			    }
			}
 
			private function moduleErrorHandler(event:ModuleEvent):void
			{
			    unloadModule();
			    dispatchEvent(event);
			}
 
			private function moduleUnloadHandler(event:ModuleEvent):void
			{
			    dispatchEvent(event);
			}
 
			override public function unloadModule():void
			{
			    if (child)
			    {
			        removeChild(child);
			        child = null;
			    }
 
			    if (module)
			    {
			        module.removeEventListener(ModuleEvent.PROGRESS,
			                                   moduleProgressHandler);
			        module.removeEventListener(ModuleEvent.SETUP, moduleSetupHandler);
			        module.removeEventListener(ModuleEvent.READY, moduleReadyHandler);
			        module.removeEventListener(ModuleEvent.ERROR, moduleErrorHandler);
 
			        module.unload();
			        module.removeEventListener(ModuleEvent.UNLOAD, moduleUnloadHandler);
			        module = null;
			    }
			}
		]]>
	</mx:Script>
</mx:ModuleLoader>